home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Aminet 5
/
Aminet 5 - March 1995.iso
/
Aminet
/
util
/
misc
/
ftrans12.lha
/
FTrans.rexx
< prev
next >
Wrap
OS/2 REXX Batch file
|
1994-04-22
|
4KB
|
217 lines
/* $VER: FTrans.rexx 1.0 (Jan 3 1994)
*
* Arexx-Script für FTrans Arexx-Interface (c) Copyright 1993 by Rainer Hess
*
* May 21 1993, Oct 22 1993, Dec 21 1993, Dec 26 1993, Dec 30 1993
* Dec 31 1993, Jan 3 1994,
*/
options results
/*
* Wir definieren unsere Eingabe und Ausgabedatei, ebenso unseren
* Publicscreen. Diese brauchen wir später in diesem Arexx-Script.
*
* ACHHTUNG! Die Eingabedatei die in 'indat' initalisiert wird sollte
* existieren da wir sonst eine Fehlermeldung bekommen. Ebenso sollte
* der Publicscreen vorhanden sein, geht aber auch ohne.
*/
indat = "RAM:AlteTextDatei"
outdat = "RAM:NeueTextDatei"
newpubscreenname = "CygnusEdScreen1"
/*
* rexxsupport.library einbinden.
*/
if ~show('l',"rexxsupport.library") then do
call addlib 'rexxsupport.library',0,-30,0
if (result = 0) then do
say "Die rexxsupport.library kann nicht eingebunden werden!"
say "Evtl. ist die rexxsupport.library nicht installiert..."
exit
end
end
/*
* Läuft unser Ftrans mit ARexx-Port "rexx_FTrans"?
*/
ok = show("P","rexx_FTrans")
if ok = 0 then do
say 'Entschuldigung, das Programm FTrans mit Arexx-Port rexx_FTrans läuft nicht!'
exit 0
end
/*
* Text auf das Shell-Fenster ausgeben in dem
* der Arexx-Script gestartet wurde.
*/
say ' - Start...'
say
/*
* Arexx-Port aktivieren.
*/
address 'rexx_FTrans'
/*
* Und den ersten Arexx-Befehl zu FTrans senden.
* FTEcho "ON" gibt Informationen im Info-Fenster von FTrans aus.
* FTEcho "OFF" wuerde dies unterbinden.
*/
FTEcho "on"
say "-> FTEcho ist" result
say
/*
* Nun einen Text auf das Info-Fenster von FTrans ausgeben.
* Danach 1 Sekunde (50 Ticks = 1 Sekunde) warten.
*/
Message "Hallo ich soll Dich von FTrans informieren..."
ok = delay(50)
/*
* Nun Wechseln wir die Übersetzungsart. Was dann aktiviert
* ist bekommen wir als Text zurückgeliefert (TEXT oder WORT).
* Danach wieder 1 Sekunde warten. Einfach so zum Überblick...
*/
Wechsel
say "-> Wechsel, nun aktive Übersetzung:" result
ok = delay(50)
/*
* Nun übersetzen wir den Text von Datei indat und der Datei outdat.
* Sollte eine Datei nicht gefunden werden, bekommen wir einen Fehler!
*/
say
say "-> Übersetze" indat "nach" outdat
Text indat outdat
say "-> Text:" result
/*
* Nun ein Wort von der Shell abholen.
*/
say
options prompt "-> Bitte ein Wort eingeben: "
parse pull eingabe
/*
* Das Wort in eine Datei schreiben von dort aus kann es Ftrans übernehmen.
*/
ok = open("DateiName", "t:FTransEingabe", "W")
ok = writech( "DateiName", eingabe )
ok = close("DateiName")
/*
* FTrans holt das Wort aus der Datei und sucht im Wörter nach der Übersetzung.
* Wurde es nicht gefunden steht es in den geschweiften Blockklammern { und }.
*/
Wort "t:FTransEingabe"
say " Ergebnis:" result
/*
* Nun wird der Dos-Befehl Delete ausgeführt. Dieser sollte sich im C:
* Direktorie befinden. Ist er da wird die Übergabedatei gelöscht.
*/
if exists('c:delete') then
address command 'c:delete' ">NIL: t:FTransEingabe"
else say 'Dos-Befehl c:Delete ist nicht zu finden...'
/*
* Arexx-Port wieder aktivieren.
*/
address 'rexx_FTrans'
/*
* Den alten Publicscreen merken.
*/
say
OLDPUBLICSCREEN
oldpub=result
say "-> Alter PublicScreen:" oldpub
/*
* Den neuen Publicscreen setzen.
*/
say
PUBLICSCREEN newpubscreenname
say "-> Neuer PublicScreen:" result
/*
* Und den alten wieder verwenden.
*/
say
PUBLICSCREEN oldpub
say "-> Alter PublicScreen:" result
/*
* Aktuelles Wöterbuch deaktivieren
* (und 5 Sekunden warten, um es besser beobachten zu können)
*/
say
DELOAD
say "-> Wörterbuch deaktiviert"
ok = delay(5 * 50)
/*
* Aktuelles Wöterbuch reaktivieren
*/
say
RELOAD
say "-> Wörterbuch reaktiviert"
/*
* Lernbuffer löschen
*/
say
LERNFLUSH
say "-> Lernbuffer gelöscht"
/*
* Merkbuffer löschen
*/
say
MERKFLUSH
say "-> Merkbuffer gelöscht"
/*
* Eine letzte Information auf das Info-Fenster von FTrans ausgeben.
*/
Message "--- Danke das war's - FTrans Arexx-Script beendet ---"
/*
* Und ebenfalls noch eine letzte Meldung auf das Shell-Fenster.
*/
say
say " *** Danke das war's - FTrans Arexx-Script beendet. ***"
/*
* Script Ende, alles ok.
*/
exit 0